; 1/21/96 - modified 3/97 for PPP login changes
;
; Win95 Plus script file 'xnet.scp' demonstrates how to
; establish an automatic PPP connection with XNet.
; Win95 PPP script modified by efflandt@xnet.com
;
; Put this script in '/Program Files/Accessories'.
; * See end of script for additional setup details *
;
; NOTE: In the password window that pops up make sure
; you change the default name to your PPP "p_username"
; (name may not stick until 1st successful connect).
;
; A script file must have a 'main' procedure.
; All script execution starts with this 'main'
; procedure.
;

; Main entry point to script
;
proc main

   ; Change these variables to customize for your
   ; specific Internet service provider

   integer nTries = 2

   ; This is the login prompt and timeout values

   string szLogin = "ogin:"
   integer nLoginTimeout = 30

   ; This is the password prompt and timeout values

   string szPW = "assword:"
   integer nPWTimeout = 15

   ; -----------------------------------------------------


   ; Attempt to login at most 'nTries' times

   while 0 < nTries do

      ; Wait for the login prompt before entering
      ; the user ID, timeout after x seconds

      waitfor szLogin then DoLogin 
        until nLoginTimeout

TryAgain:
      transmit "^M"        ; ping
      nTries = nTries - 1

   endwhile

   goto BailOut

DoLogin:
   ; Enter user ID

   transmit $USERID, raw
   transmit "^M"

   ; Wait for the password prompt 

   waitfor szPW until nPWTimeout
   if FALSE == $SUCCESS then
      goto TryAgain
   endif

   ; Send the password

   transmit $PASSWORD, raw
   transmit "^M"

   goto Done

BailOut:
   ; Something isn't responding.  Halt the script
   ; and let the user handle it manually.

   set screen keyboard on
   halt

Done:

endproc

; * Win95 setup *
;
; In Dial-Up Networking in My Computer:
; - Make New Connection for XNet
; Besides obvious settings check the following:
; - Properties - General - Server Type
; Advanced Options:
;  No  - Log on to Network
;  Yes - Enable software compression
;  No  - Require encrypted password
; Allowed network protocols:
;  No  - NetBEUI
;  No  - IPX/SPX compatible
;  Yes - TCP/IP
;
; - TCP/IP settings:
;  specify IP address
;  specify name server addresses
;  Yes - Use IP header compression
;  Yes - Use default gateway to remote network
;
; Program Files/Accessories/Dial-Up Scripting Tool
; (Scriptor) Associate the script with the Connection.
; Do for each XNet connection (different phone numbers).
;
; From The Internet - Properties you can select the
; primary connection from the drop down list.
;
; See Help "internet" for more info.